Applikation zum Web-IO Digital:

Web-IO Digital mit Delphi steuern und überwachen

Weitere Links

Als einfach zu erlernende Hochsprache bietet Delphi alles, was zum Programmieren von TCP/IP-Anwendungen nötig ist. Damit ist Delphi auch ein beliebtes Hilfsmittel, um Anwendungen zu erstellen, die mit dem Web‑IO Digital kommunizieren. Zusätzliche Treiber oder DLLs werden nicht benötigt.

Mit dem folgenden Programmbeispiel können Sie Ihr Web-IO Digital mit seinen Inputs und Outputs in einer Windows-Anwendung abbilden. Darüber hinaus können Sie die Outputs des Web-IO schalten.

Vorbereitungen

Web-IO mit Spannung versorgen und IOs verdrahten
Web-IO mit dem Netzwerk verbinden
IP-Adressen vergeben
Beim Web-IO im Bereich Kommunikationswege >> Socket-API die TCP-ASCII-Sockets aktivieren und die Outputs zum Schalten freigeben

Zusammenstellen der verschiedenen Bedienelemente und Anzeigeobjekte im Delphi-Form

Bei der Benennung der einzelnen Objekte ist es hilfreich, sinngebende Namen zu verwenden. In diesem Beipiel beschreibt der erste Teil des Namens die Art des Objektes und der zweite Teil die Funktion.

Programmstart

Einrichten der Bedienelemente

Die Gruppe mit den Bedienelementen für das Web-IO wird zunächst für die Bedienung gesperrt. In der Statuszeile wird angezeigt, dass noch keine Verbindung besteht.


procedure Twebio_ascii_client.FormCreate(Sender:TObject);
begin
  StatusBar1.SimpleText := 'No Connection';
  bt_disconnect.Enabled := False;
  gb_io.Enabled := False;
end;

Die Verbindungskontrolle

Einleiten der Verbindung

Durch Eingabe der IP-Adresse des Web-IO in das Textfeld ed_ip und Klick auf den Button bt_connect wird der Verbindungsaufbau gestartet.


procedure Twebio_ascii_client.bt_connectClick(Sender:TObject);
begin
  if ed_ip.Text <> '' then
  begin
    ClientSocket1.Host := ed_ip.Text;
    ClientSocket1.Port := strtoint(ed_port.Text);
    ClientSocket1.Active := True;
    end;
end;

Verbindung kommt zustande

Sobald das Web-IO die Verbindung annimmt, führt das ClintSocket-Steuerelement die entsprechende Prozedur aus. In der Statuszeile wird das Zustandekommen der Verbindung angezeigt, die Bedienelemente werden zur Benutzung freigegeben und der Disconnect-Button wird bedienbar.


procedure Twebio_ascii_client.ClientSocket1Connect(Sender:TObject;Socket: TCustomWinSocket);
begin
  StatusBar1.SimpleText := 'Connected to ' + ed_ip.Text;
  bt_disconnect.Enabled := True;
  gb_io.Enabled := True;
end;

Verbindungsaufbau

Für die Abwicklung des TCP/IP-Handlings wird das ClientSocket-Steuerelement von Delphi benutzt.
Dieses Steuerelement erlaubt es, bei Eintreten verschiedener Verbindungszustände Prozeduren vorzugeben und zu starten, wie hier für den Versuch eines Verbindungsaufbaus. Die Prozedur trägt eine entsprechende Meldung in die Statuszeile ein und deaktiviert den Button bt_connect, damit der Anwender keinen zweiten Verbindungsversuch unternimmt, während der erste noch läuft.


procedure Twebio_ascii_client.ClientSocket1Connecting(Sender:TObject;Socket: TCustomWinSocket);
begin
  StatusBar1.SimpleText := 'Try to connect to ' + ed_ip.Text;
  bt_connect.Enabled := False;
end;

Verbindung kommt zustande


procedure Twebio_ascii_client.ClientSocket1Connect(Sender:TObject;Socket: TCustomWinSocket);
begin
  StatusBar1.SimpleText := 'Connected to ' + ed_ip.Text;
  bt_disconnect.Enabled := True;
  gb_io.Enabled := True;
end;

Trennen der Verbindung

Die Verbindung bleibt solange bestehen, bis sie vom Benutzer durch Klick auf den Disconnect-Button beendet wird oder das Web-IO die Verbindung beendet.


procedure Twebio_ascii_client.bt_disconnectClick(Sender:TObject);
begin
  ClientSocket1.Active := False;
end;

Auch in diesem Fall ruft das ClientSocket-Steuerelement eine entsprechende Prozedur auf


procedure Twebio_ascii_client.ClientSocket1Disconnect(Sender:TObject;Socket: TCustomWinSocket);
begin
  ClientSocket1.Active := False;
  	StatusBar1.SimpleText := 'No Connection';
  bt_connect.Enabled := True;
  bt_disconnect.Enabled := False;
  gb_io.Enabled := False;
end;

Verbindungsfehler

Auch im Fall eines Verbindungsfehlers führt das ClientSocket-Steuerelement eine entsprechende Prozedure aus, die im Groben der Disconnect Prozedur entspricht. In der Statuszeile wird zusätzlich die Winsock-Fehlernummer mit ausgegeben und der ErrorCode wird abschließend auf 0 gesetzt, damit es nicht zu einem Laufzeitfehler kommt.


procedure Twebio_ascii_client.ClientSocket1Error(Sender:TObject;Socket: TCustomWinSocket; ErrorEvent: TErrorEvent;var ErrorCode: Integer);
begin
  ClientSocket1.Active := False;
  StatusBar1.SimpleText := 'Error ' + inttostr(ErrorCode) + ' - No Connection';
  ErrorCode := 0;
  bt_connect.Enabled := True;
  bt_disconnect.Enabled := False;
  gb_io.Enabled := False;
end;

Bedienung und Kommunikation von Client-Seite

Sobald eine Verbindung mit dem Web-IO zustande gekommen ist, kann der Anwender durch Bedienung der entsprechenden Programmelemente Kommandos an das Web-IO senden

Setzen der Outputs

Das Setzen der Outputs wird dem Anwender über zwei Checkboxen cb_outputx ermöglicht. Das Programm nutzt dazu das MouseUP-Ereignis dieses Objektes. Wird ein Mouse Up, also ein Loslassen der Output-Checkbox registriert, führt das Programm die entsprechende Prozedur aus und gibt - je nach dem ob die Checkbox gesetzt ist oder nicht - das passende Kommando an das Web-IO weiter.


procedure Twebio_ascii_client.cb_outputMouseUp(Sender:TObject;Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  if sender = cb_output0 then
    if cb_output0.Checked then
      ClientSocket1.Socket.SendText('GET/outputaccess0?PW=' + ed_password.Text + '&State=ON&')
    else
      ClientSocket1.Socket.SendText('GET/outputaccess0?PW=' + ed_password.Text + '&State=OFF&')
  else
    if cb_output1.Checked then
      ClientSocket1.Socket.SendText('GET/outputaccess1?PW=' + ed_password.Text + '&State=ON&')
    else
      ClientSocket1.Socket.SendText('GET/outputaccess1?PW=' + ed_password.Text + '&State=OFF&');
end;

Output/Input-Status abfragen

Den Status der Outputs und Inputs kann der Anwender durch anklicken des zugehörigen Buttons anfordern.


procedure Twebio_ascii_client.bt_outputs_readClick(Sender:TObject);
begin
  ClientSocket1.Socket.SendText('GET/output?PW=' + ed_password.Text + '&');
end;

procedure Twebio_ascii_client.bt_inputs_readClick(Sender:TObject);
begin
  ClientSocket1.Socket.SendText('GET/input?PW=' + ed_password.Text + '&');
end;

Counter abfragen löschen

Auch die Zählerstände der Input-Counter lassen sich abfragen bzw. löschen.


procedure Twebio_ascii_client.bt_counter_readClick(Sender:TObject);
begin
  if sender = bt_counter_read0 then
    ClientSocket1.Socket.SendText('GET/counter0?PW=' + ed_password.Text + '&')
  else
    ClientSocket1.Socket.SendText('GET/counter1?PW=' + ed_password.Text + '&');
end;

procedure Twebio_ascii_client.bt_counter_clearClick(Sender:TObject);
begin
  if sender = bt_counter_clear0 then
    ClientSocket1.Socket.SendText('GET /counterclear0?PW='+ ed_password.Text + '&')
  else
    ClientSocket1.Socket.SendText('GET /counterclear1?PW='+ ed_password.Text + '&');
end;

Natürlich lassen sich auch alle Counter zeitgleich lesen bzw. löschen.


procedure Twebio_ascii_client.bt_counter_readallClick(Sender:TObject);
begin
  ClientSocket1.Socket.SendText('GET/counter?PW=' + ed_password.Text + '&')
end;

procedure Twebio_ascii_client.bt_counter_clearallClick(Sender:TObject);
begin
  ClientSocket1.Socket.SendText('GET /counterclear?PW=' + ed_password.Text + '&')
end;

Datenempfang vom Web-IO

Auswerten und Anzeigen der empfangenen Daten

Alle Kommandos und Anfragen an das Web-IO werden mit einem Antwort-String quittiert. Dabei haben die Antworten je nach Type einen spezifischen Aufbau.

Für die Outputs: output;<Binärwert des Outputstatus im hexadezimalen Format>
Für die Inputs: input;<Binärwert des Outputstatus im hexadezimalen Format>
Für die Counter: counterx;<dezimaler Zählerstand>
oder counter;<dezimaler Zählerstand 0 >; <dezimaler Zählerstand 0 >; ...... wenn alle Counter auf einmal gelesen werden sollen.
Alle Antwort-Strings sind mit einem 0-Byte abgeschlossen.
Werden vom ClientSocket Steuerelement Daten empfangen, ruft dieses die entsprechende Prozedur auf


procedure Twebio_ascii_client.ClientSocket1Read(Sender:TObject;Socket: TCustomWinSocket);
var
  ReceiveString : String;
  OutputValue : word;
  InputValue : word;
begin
  ReceiveString := ClientSocket1.Socket.ReceiveText;
  if Receivestring[1] = 'o' then
  begin
    OutputValue := HextoInt(copy(ReceiveString,pos(';',ReceiveString)+1,length(ReceiveString)-pos(';',ReceiveString)-1));
    if OutputValue and 1 = 1 then
      cb_output0.Checked := True
    else
      cb_output0.Checked := False;
    if OutputValue and 2 = 2 then
      cb_output1.Checked := True
    else
      cb_output1.Checked := False;
  end;
  if Receivestring[1] = 'i' then
  begin
    InputValue := HextoInt(copy(ReceiveString,pos(';',ReceiveString)+1,length(ReceiveString)-pos(';',ReceiveString)-1));
    if InputValue and 1 = 1 then
      cb_input0.Checked := True
    else
      cb_input0.Checked := False;
    if InputValue and 2 = 2 then
      cb_input1.Checked := True
    else
      cb_input1.Checked := False;
  end;
  if Receivestring[1] = 'c' then
  begin
    if copy(ReceiveString, 8, 1) = '0'then
      ed_counter0.Text := copy(ReceiveString,10,length(ReceiveString)-10);
    if copy(ReceiveString, 8, 1) = '1'then
      ed_counter1.Text := copy(ReceiveString,10,length(ReceiveString)-10);
    if copy(ReceiveString, 8, 1) = ';'then
    begin
      ReceiveString[8] := ' ';
      ed_counter0.Text := copy(ReceiveString,9, pos(';',ReceiveString)-9);
      ed_counter1.Text := copy(ReceiveString, pos(';',ReceiveString)+1,length(ReceiveString)-pos(';',ReceiveString)-1);
    end;
  end;
end;

Die Empfangsprozedur überprüft anhand des ersten Zeichens der Empfangsdaten, ob es um Input, Output oder Counter Meldungen geht. Abhängig davon wird z.B. festgestellt, welcher Output welchen Status hat. Da der Output-Status hexadezimal übergeben wird, ist zunächst eine Wandlung in einen Integerwert nötig, um weitere Schritte zu berechnen. Zur Wandlung wurde eine entsprechende Funktion in das Programm eingebunden. Bei den Countern ist es sowohl möglich, einzelne Zählerwerte abzufragen, als auch alle Counter in einem Zug auszulesen. Die einzelnen Zählerstände werden dann dezimal mit Semikolon getrennt in einem String ausgegeben.


function HexToInt(HexString: String) : longWord;
var
  CharCount : integer;
  HexCharValue : longWord;
  HexValue : longWord;
begin
  HexValue := 0;
  HexString := UpperCase(HexString);
  for CharCount := 1 to length(HexString) do
  begin
    HexCharValue := ord(HexString[CharCount]);
    if HexCharValue > 57 then
      HexCharValue := HexCharValue -55
    else
      HexCharValue := HexCharValue -48;
    HexCharValue := HexCharValue shl ((length(HexString)- CharCount) * 4);
    HexValue := HexValue or HexCharValue;
  end;
  HexToInt := HexValue;
end;

Polling

Zyklisches Abfragen bestimmter Werte

Um auch eine automatische Aktualisierung der Anzeige zu ermöglichen, wird ein Timer benutzt.
In Abhängigkeit der Checkboxen für Output-, Input- und Counter-Polling werden die entsprechenden Informationen im eingestellten Intervall vom Web-IO abgerufen.


procedure Twebio_ascii_client.timer_pollingTimer(Sender:TObject);
begin
  if	ClientSocket1.Active and cb_output_polling.Checked then
    ClientSocket1.Socket.SendText('GET /output?PW=' + ed_password.Text + '&');
  if	ClientSocket1.Active and cb_input_polling.Checked then
    ClientSocket1.Socket.SendText('GET /input?PW=' + ed_password.Text + '&');
  if	ClientSocket1.Active and cb_counter_polling.Checked then
    ClientSocket1.Socket.SendText('GET /counter?PW=' + ed_password.Text + '&');
end;

Das gewünschte Intervall kann in das entsprechende Textfeld eingegeben werden. Bei Änderung wird das Timer-Intervall dann automatisch angepasst.


procedure Twebio_ascii_client.ed_intervalChange(Sender:TObject);
begin
  timer_polling.Interval := strtoint(ed_interval.Text);
end;

Das Beispiel Programm unterstützt alle gängigen Funktionen des Web-IO im Kommando-String Modus, optimiert für das Web-IO 2x Digital Input, 2x Digital Output PoE. Für die anderen Web-IO Modelle müssen ggf. Anpassung am Programm vorgenommen werden. Weitere Programmbeispiele zur Socket-Programmierung finden Sie auf den Tool-Seiten zum Web-IO. Eine Detaillierte Beschreibung zur Socketschnittstelle der Web-IO Digital Modelle finden Sie im Referenzhandbuch.

Programmbeispiel herunterladen

Produkte

nach oben

Web-IO Digital mit Delphi steuern und überwachen

Vorbereitungen

Zusammenstellen der verschiedenen Bedienelemente und Anzeigeobjekte im Delphi-Form

Programmstart

Die Verbindungskontrolle

Bedienung und Kommunikation von Client-Seite

Datenempfang vom Web-IO

Polling

Produkte

Web-IO 4.0 Digital
2xIn, 2xOut

Web-IO 4.0 Digital
12xIn, 12xOut

Weitere Web-IOs

Web-IO Digital mit Delphi steuern und überwachen

Vorbereitungen

Zusammenstellen der verschiedenen Bedienelemente und Anzeigeobjekte im Delphi-Form

Programmstart

Die Verbindungskontrolle

Bedienung und Kommunikation von Client-Seite

Datenempfang vom Web-IO

Polling

Produkte

Web-IO 4.0 Digital2xIn, 2xOut

Web-IO 4.0 Digital12xIn, 12xOut

Weitere Web-IOs

Web-IO 4.0 Digital
2xIn, 2xOut

Web-IO 4.0 Digital
12xIn, 12xOut