Dirigir y supervisar Web-IO digital con Delphi

Como idioma fácil de aprender Delphi ofrece todo lo que es necesario para programar aplicaciones TCP/IP. Con ello Delphi es también un auxiliar apreciado para crear aplicaciones que comunican con el Web-IO digital. No se necesitan excitadores o DLLs adicionales.

Con el ejemplo siguiente de programa puede representar su Web-IO Digital con sus Inputs y Outputs en una aplicación Windows. Además de ello puede conmutar los Outputs del Web-IO.

Preparativos

• Conectar la tensión para Web-IO y cablear las IO
• Conectar el Web-IO a la red
• Asignar las direcciones IP

• En Web-IO, dentro de la sección Vías de comunicación >> Zócalo-API activar los Zócalos TCP-ASCII y habilitar las salidas a conmutar

  

Recopilación de los diferentes elementos de manejo y objetos de visualización en formulario Delphi

Al denominar cada uno de los objetos, es de gran ayuda usar nombres con sentido. En este ejemplo la primera parte del nombre describe la clase de objeto y la segunda la función.

Arranque de programa

El grupo con los elementos de manejo para el Web-IO se bloquea primero para el manejo. En la línea de estado se visualiza que aún no hay conexión alguna.

procedure Twebio_ascii_client.FormCreate(Sender:TObject);
begin
  StatusBar1.SimpleText := ’No Connection’;
  bt_disconnect.Enabled := False;
  gb_io.Enabled := False;
end;

El control de conexión

La conexión se arranca entrando la dirección IP del Web-IO en el campo de texto ed_ip y chasqueando el botón bt_connect.

procedure Twebio_ascii_client.bt_connectClick(Sender:TObject);
begin
  if ed_ip.Text <> ’’ then
  begin
    ClientSocket1.Host := ed_ip.Text;
    ClientSocket1.Port := strtoint(ed_port.Text);
    ClientSocket1.Active := True;
    end;
end;

Tan pronto como el Web-IO acepta la conexión, el elemento de mando ClintSocket ejecuta el procedimiento correspondiente. En la línea de estado aparece la realización de la conexión, los elementos de manejo se liberan para el uso y puede manejarse el botón Disconnect.

procedure Twebio_ascii_client.ClientSocket1Connect(Sender:TObject;Socket: TCustomWinSocket);
begin
  StatusBar1.SimpleText := ’Connected to ’ + ed_ip.Text;
  bt_disconnect.Enabled := True;
  gb_io.Enabled := True;
end;

Para la tramitación del manejo TCP/IP la utiliza el elemento de mando CientSocket de Delphi.
Este elemento de mando permite prefijar e iniciar procedimientos al aparecer diversos estados de conexión, como por ejemplo aquí para el ensayo de una conexión. El procedimiento registra un mensaje correspondiente en la línea de estado y desactiva el botón bt_connect, para que el usuario no pueda realizar ningún segundo intento de conexión, mientras funciona todavía el primero.

procedure Twebio_ascii_client.ClientSocket1Connecting(Sender:TObject;Socket: TCustomWinSocket);
begin
  StatusBar1.SimpleText := ’Try to connect to ’ + ed_ip.Text;
  bt_connect.Enabled := False;
end;

Tan pronto como el Web-IO acepta la conexión, el elemento de mando ClintSocket ejecuta el procedimiento correspondiente. En la línea de estado aparece la realización de la conexión, los elementos de manejo se liberan para el uso y puede manejarse el botón Disconnect.

procedure Twebio_ascii_client.ClientSocket1Connect(Sender:TObject;Socket: TCustomWinSocket);
begin
  StatusBar1.SimpleText := ’Connected to ’ + ed_ip.Text;
  bt_disconnect.Enabled := True;
  gb_io.Enabled := True;
end;

La conexión permanece tanto tiempo hasta que el usuario la finalice chasqueando el botón Disconnect o el Web-IO finalice la conexión.

procedure Twebio_ascii_client.bt_disconnectClick(Sender:TObject);
begin
  ClientSocket1.Active := False;
end;

En este caso el elemento de mando ClientSocket también llama un procedimiento correspondiente

procedure Twebio_ascii_client.ClientSocket1Disconnect(Sender:TObject;Socket: TCustomWinSocket);
begin
  ClientSocket1.Active := False;
  	StatusBar1.SimpleText := ’No Connection’;
  bt_connect.Enabled := True;
  bt_disconnect.Enabled := False;
  gb_io.Enabled := False;
end;

En el caso de un error de conexión el elemento de mando ClientSocket también ejecuta un correspondiente procedimiento, que corresponde en general al del Disconnect. En la línea de estado se visualiza adicionalmente el número de error Winsock y el ErrorCode se pone finalmente a 0 para que no se dé un error de funcionamiento.

procedure Twebio_ascii_client.ClientSocket1Error(Sender:TObject;Socket: TCustomWinSocket; ErrorEvent: TErrorEvent;var ErrorCode: Integer);
begin
  ClientSocket1.Active := False;
  StatusBar1.SimpleText := ’Error ’ + inttostr(ErrorCode) + ’ - No Connection’;
  ErrorCode := 0;
  bt_connect.Enabled := True;
  bt_disconnect.Enabled := False;
  gb_io.Enabled := False;
end;

Manejo y comunicación por parte del cliente

Tan pronto como se ha establecido la conexión con el Web-IO, el usuario puede enviar comandos al Web-IO manejando los correspondientes elementos de programa

El usuario puede poner los Outputs a través de dos casillas de verificación cb_outputx. El programa utiliza para ello el suceso de MouseUP de este objeto. Si se registra un Mouse Up, es decir soltar la caja de chequeo Output, el programa realiza el correspondiente procedimiento y transmite el adecuado comando al Web-IO - según si está puesta la casilla o no.

procedure Twebio_ascii_client.cb_outputMouseUp(Sender:TObject;Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  if sender = cb_output0 then
    if cb_output0.Checked then
      ClientSocket1.Socket.SendText(’GET/outputaccess0?PW=’ + ed_password.Text + ’&State=ON&’)
    else
      ClientSocket1.Socket.SendText(’GET/outputaccess0?PW=’ + ed_password.Text + ’&State=OFF&’)
  else
    if cb_output1.Checked then
      ClientSocket1.Socket.SendText(’GET/outputaccess1?PW=’ + ed_password.Text + ’&State=ON&’)
    else
      ClientSocket1.Socket.SendText(’GET/outputaccess1?PW=’ + ed_password.Text + ’&State=OFF&’);
end;

El usuario puede solicitar el estado de los Outputs e Inputs chasqueando el botón correspondiente.

procedure Twebio_ascii_client.bt_outputs_readClick(Sender:TObject);
begin
  ClientSocket1.Socket.SendText(’GET/output?PW=’ + ed_password.Text + ’&’);
end;

procedure Twebio_ascii_client.bt_inputs_readClick(Sender:TObject);
begin
  ClientSocket1.Socket.SendText(’GET/input?PW=’ + ed_password.Text + ’&’);
end;

También se pueden preguntar o borrar los estados de contador de los Input-Counter.

procedure Twebio_ascii_client.bt_counter_readClick(Sender:TObject);
begin
  if sender = bt_counter_read0 then
    ClientSocket1.Socket.SendText(’GET/counter0?PW=’ + ed_password.Text + ’&’)
  else
    ClientSocket1.Socket.SendText(’GET/counter1?PW=’ + ed_password.Text + ’&’);
end;

procedure Twebio_ascii_client.bt_counter_clearClick(Sender:TObject);
begin
  if sender = bt_counter_clear0 then
    ClientSocket1.Socket.SendText(’GET /counterclear0?PW=’+ ed_password.Text + ’&’)
  else
    ClientSocket1.Socket.SendText(’GET /counterclear1?PW=’+ ed_password.Text + ’&’);
end;

Naturalmente también se pueden leer o borrar al mismo tiempo todos los contadores.

procedure Twebio_ascii_client.bt_counter_readallClick(Sender:TObject);
begin
  ClientSocket1.Socket.SendText(’GET/counter?PW=’ + ed_password.Text + ’&’)
end; 

procedure Twebio_ascii_client.bt_counter_clearallClick(Sender:TObject);
begin
  ClientSocket1.Socket.SendText(’GET /counterclear?PW=’ + ed_password.Text + ’&’)
end;

Recepción de datos del Web-IO

Todos los comandos y solicitudes al Web-IO se confirman con un String de respuesta. Aquí las respuestas presentan una estructura específica según el tipo.

• Para los Outputs: output;<valor binario del estado de salida en formato hexadecimal>
• Para los Inputs: input;<valor binario del estado de salida en formato hexadecimal>
• Para los contadores: counterx;<estado decimal de contador >
• o counter;<estado decimal de contador 0 >; <estado decimal de contador 0 >; ...... si todos los contadores se deben leer de una sola vez.
• Todos los Strings de respuesta se finalizan con un Byte 0.
• Si el elemento de mando ClientSocket recibe datos, éste llama al procedimiento correspondiente

procedure Twebio_ascii_client.ClientSocket1Read(Sender:TObject;Socket: TCustomWinSocket);
var 
  ReceiveString : String;
  OutputValue : word;
  InputValue : word;
begin
  ReceiveString := ClientSocket1.Socket.ReceiveText;
  if Receivestring[1] = ’o’ then
  begin
    OutputValue := HextoInt(copy(ReceiveString,pos(’;’,ReceiveString)+1,length(ReceiveString)-pos(’;’,ReceiveString)-1));
    if OutputValue and 1 = 1 then
      cb_output0.Checked := True
    else
      cb_output0.Checked := False;
    if OutputValue and 2 = 2 then
      cb_output1.Checked := True
    else
      cb_output1.Checked := False;
  end;
  if Receivestring[1] = ’i’ then
  begin
    InputValue := HextoInt(copy(ReceiveString,pos(’;’,ReceiveString)+1,length(ReceiveString)-pos(’;’,ReceiveString)-1));
    if InputValue and 1 = 1 then
      cb_input0.Checked := True
    else
      cb_input0.Checked := False;
    if InputValue and 2 = 2 then
      cb_input1.Checked := True
    else
      cb_input1.Checked := False;
  end;
  if Receivestring[1] = ’c’ then
  begin
    if copy(ReceiveString, 8, 1) = ’0’then
      ed_counter0.Text := copy(ReceiveString,10,length(ReceiveString)-10);
    if copy(ReceiveString, 8, 1) = ’1’then
      ed_counter1.Text := copy(ReceiveString,10,length(ReceiveString)-10);
    if copy(ReceiveString, 8, 1) = ’;’then
    begin
      ReceiveString[8] := ’ ’;
      ed_counter0.Text := copy(ReceiveString,9, pos(’;’,ReceiveString)-9);
      ed_counter1.Text := copy(ReceiveString, pos(’;’,ReceiveString)+1,length(ReceiveString)-pos(’;’,ReceiveString)-1);
    end;
  end;
end;
							

El procedimiento de recepción verifica según el primer signo de los datos de recepción, si se trata de un Input, Output o de mensajes del contador. Dependiendo de ello se constata p. ej. qué Output tiene qué estado. Puesto que el estado de Output se transmite hexadecimal, primero es necesario una conversión en un valor íntegro para calcular otros pasos más. Para la conversión se integró una función correspondiente en el programa. En los contadores es posible tanto preguntar valores de contador separados como también leer todos los contadores de un viaje. Cada uno de los estados de contador se emiten decimalmente separados por punto y coma en una cadena (String).

function HexToInt(HexString: String) : longWord;
var 
  CharCount : integer;
  HexCharValue : longWord;
  HexValue : longWord;
begin
  HexValue := 0;
  HexString := UpperCase(HexString);
  for CharCount := 1 to length(HexString) do
  begin
    HexCharValue := ord(HexString[CharCount]);
    if HexCharValue > 57 then
      HexCharValue := HexCharValue -55
    else
      HexCharValue := HexCharValue -48;
    HexCharValue := HexCharValue shl ((length(HexString)- CharCount) * 4);
    HexValue := HexValue or HexCharValue;
  end;
  HexToInt := HexValue;
end;

Polling

A fin de posibilitar una actualización automática de la indicación, se utiliza un Timer.
Dependiendo de las casillas de verificación para el Polling de Output, Input y Counter se llaman las informaciones correspondientes a un intervalo ajustado del Web-IO.

procedure Twebio_ascii_client.timer_pollingTimer(Sender:TObject);
begin
  if	ClientSocket1.Active and cb_output_polling.Checked then
    ClientSocket1.Socket.SendText(’GET /output?PW=’ + ed_password.Text + ’&’);
  if	ClientSocket1.Active and cb_input_polling.Checked then
    ClientSocket1.Socket.SendText(’GET /input?PW=’ + ed_password.Text + ’&’);
  if	ClientSocket1.Active and cb_counter_polling.Checked then
    ClientSocket1.Socket.SendText(’GET /counter?PW=’ + ed_password.Text + ’&’);
end;

El intervalo deseado puede entrarse en el campo correspondiente de texto. En caso de un cambio el intervalo del Timer se adapta automáticamente.

procedure Twebio_ascii_client.ed_intervalChange(Sender:TObject);
begin
  timer_polling.Interval := strtoint(ed_interval.Text);
end;

El programa ejemplo asiste todas las funciones corrientes del Web-IO en el modo String de comando, optimado para el Web-IO 2x Digital Input, 2x Digital Output PoE. Para los otros modelos Web-IO tienen que realizarse en caso necesario adaptaciones en el programa. Otros ejemplos de programa para la programación del zócalo los encontrarán en las páginas de herramientas al Web-IO. Una descripción detallada de la interfaz del zócalo de los modelos Web-IO digitales la encontrarán en el manual de referencia.

Productos